#compdef symfony

_symfony() {
  local curcontext="$curcontext" state line expl ret=1

  _arguments -C \
    '(-n --dry-run)'{-n,--dry-run}'[Do a dry run without executing actions.]' \
    '(-H --help)'{-H,--help}'[Display this help message.]' \
    '(-I --libdir)'{-I,--libdir=}'[Include LIBDIR in the search path for required modules.]' \
    '(-N --nosearch)'{-N,--nosearch}'[Do not search parent directories for the Rakefile.]' \
    '(-P --prereqs)'{-P,--prereqs}'[Display the tasks and dependencies, then exit.]' \
    '(-q --quiet)'{-q,--quiet}'[Do not log messages to standard output.]' \
    '(-r --require)'{-r,--require=}'[Require MODULE before executing pakefile.]' \
    '(-f --pakefile)'{-f+,--pakefile}'[Use FILE as the pakefile.]' \
    '(-T --tasks)'{-T,--tasks}'[Display the tasks and dependencies, then exit.]' \
    '(-t --trace)'{-t,--trace}'[Turn on invoke/execute tracing, enable full backtrace.]' \
    '(-h --usage)'{-h,--usage}'[Display usage.]' \
    '(-v --verbose)'{-v,--verbose}'[Log message to standard output (default).]' \
    '(-V --version)'{-V,--version}'[Display the program version.]' \
    '*::symfony command:->symfony-commands' \
    && ret=0

  if [[ -n "$state" ]]; then
    if (( CURRENT == 1 )); then
      _wanted commands expl 'symfony command' compadd - \
      freeze unfreeze init-project init-app init-module \
      clear-cache fix-perm sync  test propel-build-model \
      propel-build-sql build-sql propel-build-schema propel-build-db \
      propel-insert-sql insert-sql upgrade downgrade propel-init-crud \
      init-propelcrud generate-propelcrud propel-init-admin init-propeladmin \
      server plugin-install plugin-upgrade plugin-unintall plugin-upgrade-all \
      project_exists app_exists module_exists \
      && ret=0
    fi
  fi

  return ret
}